kos_programs/stager.ks

clearscreen.
declare function dt {
	SET dtim TO TIME - start.
	return dtim:minute+"m"+dtim:second+"s".
}

SET terminal:width TO 22.
SET terminal:height TO 12.

SET GETVOICE(1):wave to "sine".
SET GETVOICE(1):volume to 1.
SET GETVOICE(1):decay to 0.05.
SET GETVOICE(1):attack to 0.05.
SET GETVOICE(1):sustain to 1.0.
SET GETVOICE(1):release to 0.8.

print "======================".
print "    Simple stager".
print "======================".

// TODO : detect launcher stability enhancer
// TODO : detect empty fuel stages


HUDTEXT("Stager ready. Waiting 1st stage...", 10, 2, 20, red, false).
print "Waiting takeoff...".
GETVOICE(1):PLAY( LIST(NOTE(400, .1), NOTE(300, .2)) ).
WAIT UNTIL not stage:ready.
print "Lets go !".
DECLARE start TO TIME.
print dt() + " Stage #"+stage:number.

LIST ENGINES IN elist.
UNTIL ship:obt:periapsis > 60000 AND stage:number > 0{

	FOR e IN elist {
		if e:flameout AND e:stage = stage:number
		{
			STAGE.
			GETVOICE(1):PLAY( SLIDENOTE(220,320, 0.6, 0.7) ).
			PRINT dt() + " Stage #" + stage:number.
			HUDTEXT(dt() + " Stage #" + stage:number, 3, 2, 15, blue, false).
			WAIT UNTIL STAGE:READY.
			WAIT 1.0.
			GETVOICE(1):PLAY( LIST(NOTE(400, .1), NOTE(300, .2)) ).
			LIST ENGINES IN elist.
			WAIT 1.0.
		}
	}
	wait 0.
}

HUDTEXT("[Stager] Orbit detected. Exiting...", 10, 2, 20, blue, false).
print dt() + " Orbit detected".
print "exiting...".